home *** CD-ROM | disk | FTP | other *** search
/ Transactor / Transactor_13_1986_Transactor_Publishing.d64 / 1541 format>35 (.txt) next >
Commodore BASIC  |  2023-02-26  |  1KB  |  40 lines
  1. 10 rem format a track > 35
  2. 20 rem (c) 1986 d. a. hook, all rights reserved
  3. 30 print "[147]insert blank disk, then press <return>"
  4. 40 get z$: if z$<>chr$(13) goto 40
  5. 50 input "disk name, id"; n$, id$
  6. 60 open 15, 8, 15, "n0:" + n$ + "," + id$: gosub 800
  7. 70 count=0
  8. 99 rem put jmp $0400 into buffer #3
  9. 100 print#15, "m-w"; chr$(0); chr$(6); chr$(3); chr$(76); chr$(0); chr$(4)
  10. 110 gosub 800
  11. 199 rem set to track 35/sector 0
  12. 200 print#15, "m-w"; chr$(12); chr$(0); chr$(2); chr$(35); chr$(0)
  13. 210 gosub 800
  14. 299 rem read ml into disk ram ($0400)
  15. 300 restore: for i=0 to 69: read d
  16. 310 print#15, "m-w"; chr$(i); chr$(4); chr$(1); chr$(d)
  17. 320 next
  18. 399 rem execute from $0003
  19. 400 print#15, "m-w"; chr$(3); chr$(0); chr$(1); chr$(224)
  20. 499 rem read disk error code
  21. 500 print#15, "m-r"; chr$(3); chr$(0)
  22. 510 get#15, e$: e = asc(e$)
  23. 520 if e=1 then print "done, ok": close 15: end
  24. 530 if count=10 goto 900
  25. 540 count=count+1: goto 100
  26. 800 input#15, e, e$, t, s: if e=0 then return
  27. 810 print e; e$; t; s; "failed": close 15: end
  28. 900 if e<17 then print "controller error #"; e
  29. 910 gosub 800: goto 810
  30. 1000 data 165,  34, 133,  81, 169,   1, 141,  32
  31. 1010 data   6, 169,  64, 141,  33,   6, 169,  15
  32. 1020 data 141,  34,   6, 169,  17, 133,  67,  32
  33. 1030 data  40,   4,  32,  40,   4, 230,  81, 165
  34. 1040 data  81, 201,  36, 144, 242,  76,  12, 251
  35. 1041 rem             ^^ highest track number (>35) to be formatted
  36. 1050 data 174,   0,  28, 232, 138,  41,   3, 133
  37. 1060 data  20, 173,   0,  28,  41, 252,   5,  20
  38. 1070 data 141,   0,  28, 160,   5, 162, 255, 202
  39. 1080 data 208, 253, 136, 208, 250,  96
  40.